_pkgname=protobuf
pkgname=static-compat-$_pkgname
pkgver=32.1
pkgrel=1
pkgdesc="Protocol Buffers - Google's data interchange format"
arch=('x86_64')
url='https://developers.google.com/protocol-buffers/'
license=('BSD-3-Clause')
depends=(
  'static-compat-zlib'
  'static-compat-abseil-cpp'
)
makedepends=(
  'static-compat-cmake'
  'static-compat-gtest'
  'git'
)
source=(
  git+https://github.com/protocolbuffers/protobuf.git#tag=v$pkgver
  protobuf-fix-build-type-none.patch
)
sha512sums=('fc81fd22415e12bf78825b66e11ff4e327c7b89bcea4d9a140da61f50a94a4f9dba25aac9519ec084646aaecea556f391133a52cb141d944df1c92a46533f141'
            '18bc71031bbcbc3810a9985fa670465040f06a6c104ab8079b56bdfc499bb6cec40805a0cefd455031142490a576dc60aa8000523877ac0353b93558e9beabbd')

options=(!lto)

_gemname=google-protobuf

prepare() {
  cd "$_pkgname"

  patch -p1 < ../protobuf-fix-build-type-none.patch # Fix cmake config compatibility mode
}

build() {
  source static-compat-environment
  local cmake_options=(
    -B build
    -D CMAKE_BUILD_TYPE=None
    -D CMAKE_INSTALL_PREFIX=/usr/static-compat
    -D CMAKE_C_FLAGS="$CFLAGS -ffat-lto-objects"
    -D CMAKE_CXX_FLAGS="$CXXFLAGS -ffat-lto-objects"
    -D CMAKE_SKIP_RPATH=ON
    -D protobuf_BUILD_SHARED_LIBS=OFF
    -D protobuf_USE_EXTERNAL_GTEST=ON
    -D protobuf_ABSL_PROVIDER=package
    -S "$_pkgname"
    -W no-dev
  )

  static-compat-cmake "${cmake_options[@]}"
  cmake --build build --verbose
}

check() {
  ctest --test-dir build
}

package() {
  DESTDIR="$pkgdir" cmake --install build

  cd $_pkgname
  install -vDm 644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
}
