# Contributor: David Runge <dvzrv@archlinux.org>
# Contributor: Gaetan Bisson <bisson@archlinux.org>
# Contributor: Allan McRae <allan@archlinux.org>
# Contributor: Simone Sclavi 'Ito' <darkhado@gmail.com>

_pkgname=libjpeg-turbo
pkgname=static-compat-$_pkgname
pkgver=3.2.0
pkgrel=1
pkgdesc="JPEG image codec with accelerated baseline compression and decompression"
arch=(x86_64)
url="https://libjpeg-turbo.org/"
_url="https://github.com/libjpeg-turbo/libjpeg-turbo/"
license=(
  BSD-3-Clause
  IJG
)
depends=(glibc-static-compat)
makedepends=(static-compat-cmake nasm ninja)
options=(staticlibs)
source=(
  $_url/releases/download/$pkgver/$_pkgname-$pkgver.tar.gz{,.sig}
)
sha512sums=('13536db56c16e5364690ae2d31343a203e3b653c853c1f5314d36c8eb06700e92342737f1381f0171b3eb0223384c5fbcde91b55a46576952c4e75dc049cd045'
            'SKIP')
b2sums=('c50c985f8b870ab6467181f69e10f3ec2705cb349613b9178b293f136063e302087832d87f793b3d24ab721a2f5d76271760bd244d0766ab3b8cbe48ebf50cfa'
        'SKIP')
validpgpkeys=('0338C8D8D9FDA62CF9C421BD7EC2DBB6F4DBF434') # The libjpeg-turbo Project (Signing key for official binaries) <information@libjpeg-turbo.org>

build() {
  source static-compat-environment
  local cmake_options=(
    -B build
    -DCMAKE_INSTALL_LIBDIR="$static_compat_prefix"/lib
    -DWITH_JAVA=OFF
    -DWITH_JPEG8=ON
    -G Ninja
    -S $_pkgname-$pkgver
    -W no-dev
  )
  static-compat-cmake "${cmake_options[@]}"
  cmake --build build -v
}

check() {
  source static-compat-environment
  ctest --test-dir build --output-on-failure --stop-on-failure -j$(nproc)
}

package() {
  source static-compat-environment
  export docdir="$static_compat_prefix"/share/doc/$_pkgname exampledir="$static_compat_prefix"/share/doc/$_pkgname
  DESTDIR="$pkgdir" cmake --install build -v

  install -d "$pkgdir/usr/share/licenses/$pkgname"
  install -vDm 644 $_pkgname-$pkgver/LICENSE.md -t "$pkgdir/usr/share/licenses/$pkgname/"
  install -vDm 644 $_pkgname-$pkgver/README.ijg -t "$pkgdir/usr/share/licenses/$pkgname/"
  rm -r "$pkgdir/$static_compat_prefix"/share
  find "$pkgdir/$static_compat_prefix"/lib -iname '*.so*' -delete
}
