# Contributor: Levente Polyak <anthraxx[at]archlinux[dot]org>
# Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
# Contributor: Stéphane Gaudreault <stephane@archlinux.org>
# Contributor: Jan de Groot <jgc@archlinux.org>

_pkgname=libffi
pkgname=static-compat-$_pkgname
pkgver=3.7.1
pkgrel=1
pkgdesc='Portable foreign function interface library'
arch=('x86_64')
url="http://sourceware.org/libffi"
_url="https://github.com/libffi/libffi"
license=(MIT)
depends=('glibc-static-compat')
makedepends=('static-compat-configure')
checkdepends=('dejagnu')
options=(!emptydirs staticlibs)
source=($_pkgname-$pkgver.tar.gz::$_url/archive/refs/tags/v$pkgver.tar.gz)
sha256sums=('df80a3ff1d3421ac2ae0e368575f82f30383f932481ecf2dd1d5f7f88c92f547')
b2sums=('c7527bf092321198065151f12f8651b0ae1266dbea5d3cced9dc164c5e89a1d1d6e4d34649ab6feb574a7756f7628f495a3832b1a4913c12095c95c913443952')

prepare() {
  source static-compat-environment
  cd $_pkgname-$pkgver
  autoreconf -fiv
}

build() {
  source static-compat-environment
  cd $_pkgname-$pkgver
  static-compat-configure \
    --disable-shared \
    --enable-static \
    --enable-pax_emutramp
  make
}

check() {
  source static-compat-environment
  #make -C $_pkgname-$pkgver check
}

package() {
  source static-compat-environment
  cd $_pkgname-$pkgver
  make DESTDIR="$pkgdir" install
  rm -r "$pkgdir/$static_compat_prefix"/share/{man,info}
  install -Dm 644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname
}

# vim: ts=2 sw=2 et:
